# Maintainer: Maxime Gauduin <alucryd@archlinux.org>

pkgname=pantheon-photos
pkgver=2.7.1
pkgrel=1
pkgdesc='The Pantheon Photos Manager'
arch=(x86_64)
url=https://github.com/elementary/photos
license=(GPL3)
depends=(
  cairo
  gdk-pixbuf2
  geocode-glib
  glib2
  gst-plugins-base-libs
  gstreamer
  gtk3
  json-glib
  libexif
  libgee
  libgexiv2
  libgphoto2
  libgranite.so
  libgudev-1.0.so
  libhandy-1.so
  libraw
  libsoup
  libxml2
  pango
  rest
  sqlite
)
makedepends=(
  git
  intltool
  meson
  vala
  webkit2gtk
)
optdepends=('webkit2gtk: Publishing plugins')
groups=(pantheon)
_tag=90ec10cac5cbfd6ccbb76f1b0cdc259d8366afb2
source=(pantheon-photos::git+https://github.com/elementary/photos.git#tag=${_tag})
sha256sums=(SKIP)

prepare() {
  cd pantheon-photos
}

pkgver() {
  cd pantheon-photos
  git describe --tags
}

build() {
  arch-meson pantheon-photos build \
    -Dlibunity=false
  meson compile -C build
}

package() {
  DESTDIR="${pkgdir}" meson install -C build
}

# vim: ts=2 sw=2 et:
